1. Clicking on any image in the WheelLayout mode will rotate all the elements until the selected item is centered in front. In this animation the layout runs on every frame of the animation.
2. Selecting different layouts from the drop-down will animate the items’ transformation. In this animation the layout is disabled and is not running during the animation.

Animating the Scroll Position

In the first animation I want the selected item to come “in view”. In the WheelLayout I’ve already implemented the standard API that calculates the scroll distance to an item – getScrollPositionDeltaToElement(). Now in the item renderer of the list – FlickrThumbnail.mxml – I detect when the item has been clicked and then create an animation for the scroll position of the parent Group:

protected function itemrenderer1_clickHandler(event:MouseEvent):void
{
    var g:GroupBase = parent as GroupBase;
    var p:Point = g.layout.getScrollPositionDeltaToElement(this.itemIndex);
    if (p)
    {
        var startX:Number = g.horizontalScrollPosition;
        var startY:Number = g.verticalScrollPosition;
        var anim:Animate = new Animate();
        anim.motionPaths = new [
            new SimpleMotionPath("horizontalScrollPosition", startX, startX + p.x, 500),
            new SimpleMotionPath("verticalScrollPosition", startY, startY + p.y, 500)
        ];
 
        var interpolator:NumberInterpolatorWrapping =
			new NumberInterpolatorWrapping(0, g.contentWidth - g.width);
        var scrollLength:Number = interpolator.getLength(startX, startX + p.x);
        anim.interpolator = interpolator;
        anim.duration = Math.max(550, Math.min(2500, scrollLength * 2));
 
        anim.play([g]);
    }
}

One interesting thing to note is that because of the circular nature of the WheelLayout I wanted the animation to interpolate between the values in a wrap-around manner. For example scrolling from the last element to the first element shouldn’t scroll through any other elements since the first and last elements are visually next to each other. For that reason I implemented a custom interpolator – NumberInterpolatorWrapping.as.

Animating Items between Different Layouts

In this animation I wanted all the elements to move and rotate smoothly when I switch between various layouts. In this animation the start position is defined by the current layout and the end position is defined by the new layout. In-between, while the elements are being animated, they really don’t belong to any layout. For that reason, I disable the layout of the container for the duration of the animation using the autoLayout property of the parent Group.

For convenience I transition between the layouts using states:

<s:states>
	<s:State name="tile"/>
	<s:State name="wheel"/>
	<s:State name="vertical"/>
	<s:State name="horizontal"/>
</s:states>
 
<s:List width="100%" height="100%"
		dataProvider="{photoFeed}"
		itemRenderer="FlickrThumbnail"
		id="theList" useVirtualLayout="false">
 
	<s:layout.vertical>
		<s:VerticalLayout horizontalAlign="center"/>
	</s:layout.vertical>
	<s:layout.horizontal>
		<s:HorizontalLayout verticalAlign="middle"/>
	</s:layout.horizontal>
	<s:layout.tile>
		<s:TileLayout horizontalAlign="center" verticalAlign="bottom"
                                      columnWidth="112" rowHeight="132"
				      requestedColumnCount="5"/>
	</s:layout.tile>
	<s:layout.wheel>
		<my:WheelLayout gap="20" axisAngle="{axisSlider.value}"
		verticalCenterOffset="{offsetSlider.value}"/>
	</s:layout.wheel>
</s:List>

Because the elements could be both moved and/or rotated in 2D or 3D, I use a parallel of both effects:

<fx:Declarations>
    <s:Parallel id="myEffect" effectEnd="myEffect_effectEndHandler(event)">
        <s:Move3D applyChangesPostLayout="false"/>
        <s:Rotate3D applyChangesPostLayout="false"/>
    </s:Parallel>
</fx:Declarations>

And finally, when I switch from one layout state to another, I want to run the effect. Now I need to perform the following steps:

1. Make the effect target all of the elements.
2. Capture the start values (the position and rotation defined by the old layout).
3. Switch the layout (by changing the state) and call validateNow() so that all elements are positioned and/or rotated by the new layout.
4. Turn off the autoLayout property so that the new layout doesn’t interfere with the running effect.
5. Run the effect. Note that at this point the effect is going to capture the animation end values – the position/rotation defined by the new layout. I’ve already captured the start values at step 2, so I’m all set.
6. When the effect is done, turn the layout back on.

private function animateTo(toState:String):void
{
    // Make sure any previous animation is stopped.
    if (myEffect.isPlaying)
        myEffect.stop();
 
    // Add targets
    myEffect.targets = new Array();
    for (var i:int = 0; i < theList.dataGroup.numElements; i++)
        myEffect.targets.push(theList.dataGroup.getElementAt(i));
 
    // Create Transition for all elements
    myEffect.captureStartValues();
 
    // Go to the end state
    var fromState:String = this.currentState;
    setCurrentState(toState);
 
    // Validate everything before turning off the layout
    theList.validateNow();
 
    // Turn the layout off before running the effect
    theList.dataGroup.autoLayout = false;
 
    // Play the effect
    myEffect.play();
}
 
protected function myEffect_effectEndHandler(event:EffectEvent):void
{
    theList.dataGroup.autoLayout = true;
}

Note that my demo has one limitation – I needed to turn off virtual layout so that everything works fine. If I have virtual layout running, I’m not guaranteed that the old and new layouts will assign the items to the same item renderers.
Click on the image at the top to go to the demo, where you can select “view source” from the right-click menu to get the code.

Baseline Concepts in Flex

• Each IVisualElement has a baselinePosition. This is the vertical distance from element’s top (origin) to its text base.
• To align an IVisualElement’s text to a specific point within its parent, say A=100, we roughly do the following element.y = A – element.baselinePosition.
• Each IVisualElement has a baseline constraint. How this is going to be used is up to the parent layout. By default BasicLayout/Canvas interpret it as the position within the parent to which the element’s text base should be aligned, meaning that the actual calculation is element.y = element.baseline – element.baselinePosition.

What I Want

1. Still keep all the cool functionality of the HorizontalLayout without copying code.
2. Ability to specify a global baseline. The layout should position all the elements such that their text aligns to that global baseline. I also want the ability to individually offset the elements from the global baseline. I want the element’s baseline constraint, if specified, to serve as such an offset.
3. If I’m too lazy to specify the global baseline, the layout should calculate it for me. In that case there shouldn’t be any extra space around the elements and the layout’s borders.
4. The global baseline should be [Bindable]. Since the layout is calculating it in certain cases, I want to be able to read it back whenever its value changes.

Here’s an example of the layout in action:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               xmlns:mx="library://ns.adobe.com/flex/mx"
               xmlns:local="*">
 
    <s:BorderContainer horizontalCenter="0" verticalCenter="0"
                       minWidth="0" minHeight="0">
 
        <s:layout>
             <local:HBaselineLayout verticalAlign="baseline"/>
        </s:layout>
 
        <s:CheckBox label="hello"/>
        <s:Button label="button"/>
        <s:Label text="and label"/>
 
    </s:BorderContainer>
 
</s:Application>

Implementation

1. I extended the HorizontalLayout class and had to override the verticalAlign property getter in order to modify the enum metadata and add “baseline” as an option.
2. I added a globalBaseline property. I had to override the updateDisplayList() method. After the super.updateDisplayList() has finished with sizing and positioning the elements, I’d iterate over them and position them using something like this element.setLayoutBoundsPosition(element.getLayoutBoundsX(), globalBaseline + element.baseline – element.baselinePosition).
3. Calculating the globalBaseline is easy enough. If all the elements are aligned at the globalBaseline, then a certain portion of each element will be above that line and the rest will be below the line – top portion and bottom portion. Then I have topPortion = element.baseline – element.baselinePosition and bottomPortion = element.height – element.baseline + element.baselinePosition. Now since I don’t want any extra space around the elements I want the element that sticks out the most above the globalBaseline to touch the top edge of the container, while the element that sticks out the most below the globalBaseline to touch the bottom edge of the container. Therefore the globalBaseline is going to be the maximum of the top portions, while the measured height of the container is going to be the globalBaseline + the maximum of the bottom portions. I created a helper function to calculate the maximums of the top and bottom portions and used it in the overridden measure() and updateDisplayList() methods.
4. Finally, I added a property actualBaseline and made sure to dispatch an event when it changes. I update the actualBaseline at the end of updateDisplayList() so that at the time of the event it’s certain that all elements are already sized and positioned correctly.

Here’s an example of a working app, to get the source right-click on the application and select “view source”.

Now VGroup and VerticalLayout have a “verticalAlign” property with the three supported values of “top“, “middle“, “bottom“. Accordingly HGroup and HorizontalLayout get a “horizontalAlign” property with the supported values of “left“, “center” and “right“. The alignment modes work for the layouts with and without virtualization enabled.
An important difference to note is that when “clipAndEnableScrolling” is set to “true” and the containers are scrolling (the content is bigger than the container), the Spark layouts ensure that the entire content can be scrolled in view by internally reverting to the “top“/”left” alignment respectively.

When playing with the attached sample, you’ll notice difference between the clipping and the non-clipping containers when scrolling is in effect (drag the slider left to force smaller height for the containers).

The sample was compiled with SDK version 4.0.0.13553, source: MajorAxisAlignment.mxml